Как да настроите сигнали за интернет връзка на Windows 10

Ако вашият интернет работи и трябва да следите кога имате връзка или не, най-лесният начин да го направите е да следите символа WiFi в системната област на Windows 10. Когато загубите интернет връзка, върху символа WiFi се появява жълт удивителен знак. Можете също да пингувате уебсайт. Ако не можете да държите под око системната област и ping изглежда досадно за вас, можете да настроите аудио сигнали за интернет свързаност на Windows 10 с прост скрипт.

ПРЕДУПРЕЖДЕНИЕ ЗА СПОЙЛЕР: Превъртете надолу и гледайте видеоурока в края на тази статия.

Сигнали за интернет свързаност

Този скрипт първоначално е написан от Superuser Fabby и е подобрен от VMMF. Скриптът изисква да изтеглите безплатна помощна програма, наречена Помощни програми на GNU за Win32. Разархивирайте го и потърсете в следната папка EXE, наречен Sleep.exe.

UnxUtilsusrlocalwbin

Това ще се използва за добавяне на време за изчакване между проверките. Този EXE трябва да бъде в същата папка, в която записвате скрипта. Нямате нужда от нищо друго, така че не се колебайте да го изтриете.

Отворете Notepad и поставете следното в него. Запазете го с разширение CMD и стартирайте файла. Файлът sound.vbs да бъде създаден от скрипта, така че не се притеснявайте за него.

@ECHO OFF

:whileNoInternet

set "host=8.8.8.8"

::check if internet is working

PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% neq 0 (

::the internet is not working keep cheking until it does
 echo No internet yet %TIME%
 GOTO whileNoInternet
)

echo we gained internet
::the internet is working play internet ON song

@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
 echo Sound.URL = "%file%"
 echo Sound.Controls.play
 echo do while Sound.currentmedia.duration = 0
 echo wscript.sleep 100
 echo loop
 echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet

sleep.exe 5s

::check if internet is still working

PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% == 0 (

::the internet is still working keep cheking until it does not
 echo We have internet %TIME%
 GOTO whileInternet
)

:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s

PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% == 0 (

::the internet is still working keep cheking until it does not
 echo We have internet %TIME%
 GOTO whileInternet
)

:: if it failed twice in a row most likely internet is down

echo we lost internet
::the internet is not working anymore, play internet OFF song

@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
 echo Sound.URL = "%file%"
 echo Sound.Controls.play
 echo do while Sound.currentmedia.duration = 0
 echo wscript.sleep 100
 echo loop
 echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs

::start monitoring if it comes back
GOTO whileNoInternet

Това е всичко, което трябва да направите. Прозорецът на командния ред ще остане отворен, проверявайки състоянието на вашата интернет връзка. Ако се промени, ще чуете изключен звук.